Middle Columbia River Fish Indexing Analysis 2019

Life-Stage

The four primary fish species were categorized as fry, juvenile or adult based on their lengths.

Growth

Annual growth was estimated from the inter-annual recaptures using the Fabens method (Fabens 1965) for estimating the von Bertalanffy (VB) growth curve (von Bertalanffy 1938). The VB curves is based on the premise that

\[ \frac{dl}{dt} = k (L_{\infty} - l)\]

where \(l\) is the length of the individual, \(k\) is the growth coefficient and \(L_{\infty}\) is the mean maximum length.

Integrating the above equation gives

\[ l_t = L_{\infty} (1 - e^{-k(t - t0)})\]

where \(l_t\) is the length at time \(t\) and \(t0\) is the time at which the individual would have had no length.

The Fabens form allows

\[ l_r = l_c + (L_{\infty} - l_c) (1 - e^{-kT})\]

where \(l_r\) is the length at recapture, \(l_c\) is the length at capture and \(T\) is the time at large.

Key assumptions of the growth model include:

• \(k\) can vary with discharge regime and randomly with year.
• The residual variation in growth is normally distributed.

Mountain Whitefish with a FL \(>\) 250 mm at release were excluded from the growth analysis as they appeared to be undergoing biphasic growth.

Condition

Condition was estimated via an analysis of mass-length relations (He et al. 2008).

More specifically the model was based on the allometric relationship

\[ W = \alpha L^{\beta}\]

where \(W\) is the weight (mass), \(\alpha\) is the coefficent, \(\beta\) is the exponent and \(L\) is the length.

To improve chain mixing the relation was log-transformed, i.e.,

\[ \log(W) = \log(\alpha) + \beta \log(L)\]

and the logged lengths centered, i.e., \(\log(L) - \text{mean}({\log(L)})\), prior to model fitting.

Key assumptions of the condition model include:

• \(\alpha\) can vary with the regime and season and randomly with year.
• \(\beta\) can vary with the regime and season and randomly with year.
• The residual variation in weight is log-normally distributed.

Fry were excluded from the condition analysis.

Occupancy

Occupancy, which is the probability that a particular species was present at a site, was estimated from the temporal replication of detection data (Kery and Schaub 2011, 414–18), i.e., each site was surveyed multiple times within a season. A species was considered to have been detected if one or more individuals of the species were caught or counted. It is important to note that the model estimates the probability that the species was present at a given (or typical) site in a given (or typical) year as opposed to the probability that the species was present in the entire study area. We focused on Northern Pikeminnow, Burbot, Lake Whitefish, Rainbow Trout, Redside Shiner and Sculpins because they were low enough density to not to be present at all sites at all times yet were encounted sufficiently often to provide information on spatial and temporal changes.

Key assumptions of the occupancy model include:

• Occupancy varies with season.
• Occupancy varies randomly with site and site within year.
• The effect of year on occupancy is autoregressive with a lag of one year and varies with discharge regime.
• Sites are closed, i.e., the species is present or absent at a site for all the sessions in a particular season of a year.
• Observed presence is described by a bernoulli distribution, given occupancy.

Count

The count data were analysed using an overdispersed Poisson model (Kery 2010, pp 168-170; Kery and Schaub 2011, pp 55-56) to provide estimates of the lineal river count density (count/km). The model estimates the expected count which is the product of the abundance and observer efficiency. In order to interpret the estimates as relative densities it is necessary to assume that changes in observer efficiency are negligible.

Key assumptions of the count model include:

• The count density (count/km) varies as an exponential growth model with the rate of change varying with discharge regime.
• The count density varies with season.
• The count density varies randomly with site, year and site within year.
• The counts are gamma-Poisson distributed.

In the case of suckers the count model replaced the first assumption with

• The count density varies with discharge regime.

Movement

The extent to which sites are closed, i.e., fish remain at the same site between sessions, was evaluated from a logistic ANCOVA (Kery 2010). The model estimated the probability that intra-annual recaptures were caught at the same site versus a different one.

Key assumptions of the site fidelity model include:

• Site fidelity varies with season, fish length and the interaction between season and fish length.
• Observed site fidelity is Bernoulli distributed.

Fry were excluded from the movement analysis.

Observer Length Correction

The annual bias (inaccuracy) and error (imprecision) in observer’s fish length estimates were quantified from the divergence of the length distribution of their observed fish from the length distribution of the measured fish. More specifically, the percent length correction that minimised the Jensen-Shannon divergence (Lin 1991) between the two distributions provided a measure of the inaccuracy while the minimum divergence (the Jensen-Shannon divergence was calculated with log to base 2 which means it lies between 0 and 1) provided a measure of the imprecision.

Abundance

The catch and geo-referenced count data were analysed using a capture-recapture-based overdispersed gamma-Poisson model to provide estimates of capture efficiency and absolute abundance. To maximize the number of recaptures the model grouped all the sites into a supersite for the purposes of estimating the number of marked fish but analysed the total captures at the site level.

Key assumptions of the full abundance model include:

• The density (fish/km) varies as an exponential growth model with the rate of change varying with discharge regime.
• The density varies with season.
• The density varies randomly with site, year and site within year.
• Efficiency (probability of capture) varies by season and method (capture versus count).
• Efficiency varies randomly by session within season within year.
• Marked and unmarked fish have the same probability of capture.
• There is no tag loss, migration (at the supersite level), mortality or misidentification of fish.
• The number of fish caught is gamma-Poisson distributed.
• The overdispersion varies by encounter type (count versus capture).

In the case of Adult Suckers the abundance model replaced the first assumption with

• The density varies with discharge regime.

Distribution

The site within year random effects from the count and abundance models were analysed using a linear mixed model to estimate the distribution.

Key assumptions of the linear mixed model include:

• The effect varies by river kilometer.
• The effect of river kilometer varies by discharge regime.
• The effect of river kilometer varies randomly by year.
• The effect is normally distributed.

The effects are the predicted site within year random effects after accounting for all other predictors including the site and year random effects. As such an increase in the distribution represents an increase in the relative density of fish closer to Revelstoke Dam. A positive distribution does not however necessarily indicate that the density of fish is higher closer to Revelstoke Dam.

Species Richness

The estimated probabilities of presence for the six species considered in the occupany analyses were summed to give the expected species richnesses by site and year.

Species Evenness

The site and year estimates of the lineal bank count densities from the count model for Rainbow Trout, Suckers, Burbot and Northern Pikeminnow were combined with the equivalent count estimates for Juvenile and Adult Bull Trout and Adult Mountain Whitefish from the abundance model to calculate the shannon index of evenness \((E)\). The index was calculated using the following formula where \(S\) is the number of species and \(p_i\) is the proportion of the total count belonging to the ith species.

\[ E = \frac{-\sum p_i \log(p_i)}{\log(S)}\]

Species Diversity

The site and year estimates of the lineal bank count densities from the count model for Rainbow Trout, Suckers, Burbot and Northern Pikeminnow were combined with the equivalent count estimates for Adult Bull Trout and Adult Mountain Whitefish from the abundance model to calculate species diversity profiles (Leinster and Cobbold 2012). Species diversity profiles can take similarities among species into account, allow for a range of weightings of rare versus common species (via the \(q\) sensitivity parameter), and estimate the effective number of species.

Like the species richness and evenness estimates, the species diversity profile estimates treated all species equally. The \(q\) sensitivity parameter, which measures the insensitivity to rare species, ranged from \(0\) (equivalent to richness) through \(1\) (equivalent to evenness) to \(2\) (equivalent to Simpson (1949)).

Growth

.model {

  bKIntercept ~ dnorm(0, 5^-2)

  bKRegime[1] <- 0
  for(i in 2:nRegime) {
    bKRegime[i] ~ dnorm(0, 5^-2)
  }

  sKAnnual ~ dnorm(0, 5^-2) T(0, )
  for (i in 1:nAnnual) {
    bKAnnual[i] ~ dnorm(0, sKAnnual^-2)
    log(bK[i]) <- bKIntercept + bKRegime[step(i - Threshold) + 1] + bKAnnual[i]
  }

  bLinf ~ dnorm(600, 300^-2) T(100, 1000)
  sGrowth ~ dnorm(0, 100^-2) T(0, )
  for (i in 1:length(Growth)) {

    eGrowth[i] <- (bLinf - LengthAtRelease[i]) * (1 - exp(-sum(bK[Annual[i]:(Annual[i] + Years[i] - 1)])))

    Growth[i] ~ dnorm(eGrowth[i], sGrowth^-2)
  }
  tGrowth <- bKRegime[2]
..

Block 1. The model description.

Condition

.model {

  bWeightIntercept ~ dnorm(5, 5^-2)
  bWeightSlope ~ dnorm(3, 5^-2)

  bWeightRegimeIntercept[1] <- 0
  bWeightRegimeSlope[1] <- 0

  for(i in 2:nRegime) {
    bWeightRegimeIntercept[i] ~ dnorm(0, 5^-2)
    bWeightRegimeSlope[i] ~ dnorm(0, 5^-2)
  }

  bWeightSeasonIntercept[1] <- 0
  bWeightSeasonSlope[1] <- 0
  for(i in 2:nSeason) {
    bWeightSeasonIntercept[i] ~ dnorm(0, 5^-2)
    bWeightSeasonSlope[i] ~ dnorm(0, 5^-2)
  }

  sWeightYearIntercept ~ dnorm(0, 1^-2) T(0,)
  sWeightYearSlope ~ dnorm(0, 1^-2) T(0,)
  for(yr in 1:nYear) {
    bWeightYearIntercept[yr] ~ dnorm(0, sWeightYearIntercept^-2)
    bWeightYearSlope[yr] ~ dnorm(0, sWeightYearSlope^-2)
  }

  sWeight ~ dnorm(0, 1^-2) T(0,)
  for(i in 1:length(Year)) {

    eWeightIntercept[i] <- bWeightIntercept + bWeightRegimeIntercept[Regime[i]] + bWeightSeasonIntercept[Season[i]] + bWeightYearIntercept[Year[i]]

    eWeightSlope[i] <- bWeightSlope + bWeightRegimeSlope[Regime[i]] + bWeightSeasonSlope[Season[i]] + bWeightYearSlope[Year[i]]

    log(eWeight[i]) <- eWeightIntercept[i] + eWeightSlope[i] * LogLength[i]
    Weight[i] ~ dlnorm(log(eWeight[i]) , sWeight^-2)
  }
  tCondition1 <- bWeightRegimeIntercept[2]
  tCondition2 <- bWeightRegimeSlope[2]
..

Block 2. The model description.

Occupancy

.model {

  bRate ~ dnorm(0, 5^-2)

  sRateYear ~ dnorm(0, 5^-2) T(0,)
  for(i in 1:nYear) {
    bRateYear[i] ~ dnorm(0, sRateYear^-2)
  }

  bRateRev5 ~ dnorm(0, 5^-2)

  bOccupancyYear[1] ~ dnorm(0, 5^-2)
  for (i in 2:nYear) {
    eRateYear[i-1] <- bRate + bRateYear[i-1] + bRateRev5 * YearRev5[i-1]
    bOccupancyYear[i] <- bOccupancyYear[i-1] + eRateYear[i-1]
  }

  bOccupancySpring ~ dnorm(0, 5^-2)

  sOccupancySite ~ dnorm(0, 5^-2) T(0,)
  sOccupancySiteYear ~ dnorm(0, 5^-2) T(0,)
  for (i in 1:nSite) {
    bOccupancySite[i] ~ dnorm(0, sOccupancySite^-2)
    for (j in 1:nYear) {
      bOccupancySiteYear[i,j] ~ dnorm(0, sOccupancySiteYear^-2)
    }
  }

  for (i in 1:length(Observed)) {
    logit(eObserved[i]) <- bOccupancyYear[Year[i]] + bOccupancySpring * Spring[i] + bOccupancySite[Site[i]] + bOccupancySiteYear[Site[i], Year[i]]
    Observed[i] ~ dbern(eObserved[i])
  }
..

Block 3. The model description.

Count

.model {
  bDensity ~ dnorm(0, 5^-2)

  bRate ~ dnorm(0, 5^-2)
  bRateRev5 ~ dnorm(0, 5^-2)

  bTrendYear[1] <- bDensity
  for(i in 2:nYear) {
    bTrendYear[i] <- bTrendYear[i-1] + bRate + bRateRev5 * YearRev5[i-1]
  }

  bDensitySeason[1] <- 0
  for (i in 2:nSeason) {
    bDensitySeason[i] ~ dnorm(0, 5^-2)
  }

  sDensityYear ~ dnorm(0, 5^-2) T(0,)
  for (i in 1:nYear) {
    bDensityYear[i] ~ dnorm(0, sDensityYear^-2)
  }

  sDensitySite ~ dnorm(0, 5^-2) T(0,)
  sDensitySiteYear ~ dnorm(0, 2^-2) T(0,)
  for (i in 1:nSite) {
    bDensitySite[i] ~ dnorm(0, sDensitySite^-2)
    for (j in 1:nYear) {
      bDensitySiteYear[i, j] ~ dnorm(0, sDensitySiteYear^-2)
    }
  }

  sDispersion ~ dnorm(0, 5^-2) T(0,)
  for (i in 1:length(Year)) {

    log(eDensity[i]) <- bTrendYear[Year[i]] + bDensitySeason[Season[i]] + bDensityYear[Year[i]] + bDensitySite[Site[i]] + bDensitySiteYear[Site[i],Year[i]]

    eCount[i] <- eDensity[i] * SiteLength[i] * ProportionSampled[i]
    eDispersion[i] ~ dgamma(1 / sDispersion^2, 1 / sDispersion^2)
    Count[i] ~ dpois(eCount[i] * eDispersion[i])
  }
  tCount <- bRateRev5
..

Block 4. The model description.

Movement

.model {
  bMoved ~ dnorm(0, 5^-2)
  bLength ~ dnorm(0, 5^-2)

  bMovedSpring ~ dnorm(0, 5^-5)
  bLengthSpring ~ dnorm(0, 5^-5)

  for (i in 1:length(Moved)) {
    logit(eMoved[i]) <- bMoved + bMovedSpring * Spring[i] + (bLength + bLengthSpring * Spring[i]) * Length[i]
    Moved[i] ~ dbern(eMoved[i])
  }
..

Block 5.

Abundance

.model {
  bDensity ~ dnorm(0, 5^-2)

  bRate ~ dnorm(0, 5^-2)
  bRateRev5 ~ dnorm(0, 5^-2)

  bTrendYear[1] <- bDensity
  for(i in 2:nYear) {
    bTrendYear[i] <- bTrendYear[i-1] + bRate + bRateRev5 * YearRev5[i-1]
  }

  bDensitySeason[1] <- 0
  for (i in 2:nSeason) {
    bDensitySeason[i] ~ dnorm(0, 5^-2)
  }

  sDensityYear ~ dnorm(0, 5^-2) T(0,)
  for (i in 1:nYear) {
    bDensityYear[i] ~ dnorm(0, sDensityYear^-2)
  }

  sDensitySite ~ dnorm(0, 5^-2) T(0,)
  sDensitySiteYear ~ dnorm(0, 2^-2) T(0,)
  for (i in 1:nSite) {
    bDensitySite[i] ~ dnorm(0, sDensitySite^-2)
    for (j in 1:nYear) {
      bDensitySiteYear[i, j] ~ dnorm(0, sDensitySiteYear^-2)
    }
  }

  bEfficiency ~ dnorm(0, 5^-2)

  bEfficiencySeason[1] <- 0
  for(i in 2:nSeason) {
    bEfficiencySeason[i] ~ dnorm(0, 5^-2)
  }

  sEfficiencySessionSeasonYear ~ dnorm(0, 5^-2) T(0,)
  for (i in 1:nSession) {
    for (j in 1:nSeason) {
      for (k in 1:nYear) {
        bEfficiencySessionSeasonYear[i, j, k] ~ dnorm(0, sEfficiencySessionSeasonYear^-2)
      }
    }
  }

  bMultiplier <- 0
  sDispersion ~ dnorm(0, 2^-2)
  bMultiplierType[1] <- 0
  sDispersionType[1] <- 0
  for (i in 2:nType) {
    bMultiplierType[i] ~ dnorm(0, 2^-2)
    sDispersionType[i] ~ dnorm(0, 2^-2)
  }

  for(i in 1:length(EffIndex)) {

    logit(eEff[i]) <- bEfficiency + bEfficiencySeason[Season[EffIndex[i]]] + bEfficiencySessionSeasonYear[Session[EffIndex[i]],Season[EffIndex[i]],Year[EffIndex[i]]]

    Marked[EffIndex[i]] ~ dbin(eEff[i], Tagged[EffIndex[i]])
  }

  for (i in 1:length(Year)) {

    logit(eEfficiency[i]) <- bEfficiency + bEfficiencySeason[Season[i]] + bEfficiencySessionSeasonYear[Session[i], Season[i], Year[i]]

    log(eDensity[i]) <- bTrendYear[Year[i]] + bDensitySeason[Season[i]] + bDensityYear[Year[i]] + bDensitySite[Site[i]] + bDensitySiteYear[Site[i],Year[i]]

    log(eMultiplier[i]) <- bMultiplier + bMultiplierType[Type[i]]

    eCatch[i] <- eDensity[i] * SiteLength[i] * ProportionSampled[i] * eEfficiency[i] * eMultiplier[i]

    log(esDispersion[i]) <- sDispersion + sDispersionType[Type[i]]

    eDispersion[i] ~ dgamma(esDispersion[i]^-2 + 0.1, esDispersion[i]^-2 + 0.1)

    Catch[i] ~ dpois(eCatch[i] * eDispersion[i])
  }
  tAbundance <- bRateRev5
..

Block 6. The model description.

Distribution

.model {
  bEffect ~ dnorm(0, 1^-2)

  bRkm ~ dnorm(0, 1^-2)
  bRkmRev5 ~ dnorm(0, 1^-2)

  sRkmYear ~ dnorm(0, 1^-2) T(0,)
  for(i in 1:nYear) {
    bRkmYear[i] ~ dnorm(0, sRkmYear^-2)
  }
  sEffect ~ dnorm(0, 1^-2) T(0,)
  for(i in 1:length(Effect)) {
    eEffect[i] <- bEffect + (bRkm + bRkmRev5 * Rev5[i] + bRkmYear[Year[i]]) * Rkm[i]
    Effect[i] ~ dnorm(eEffect[i], sEffect^-2)
  }
tDistribution <- bRkmRev5

Block 7. The model description.

Stage

Table 1. Length cutoffs by species and stage.

Growth

Table 2. Parameter descriptions.

Condition

Table 12. Parameter descriptions.

Occupancy

Table 25. Parameter descriptions.

Count

Table 38. Parameter descriptions.

Movement

Table 47. Parameter descriptions.

Abundance

Table 56. Parameter descriptions.

Distribution

Table 69. Parameter descriptions.

Effect Size

Table 91. The significance levels for the management hypotheses tested in the analyses. The Direction column indicates whether significant changes were positive or negative. The estimates and 95% lower and upper credible intervals are the effect sizes.

Growth

Condition

Occupancy

Count

Movement

Observer Length Correction

Abundance

Distribution

Species Richness

Species Evenness

Species Diversity

Effect Size