Lower Duncan River Kokanee AUC Analysis 2015

Data Preparation

The data were provided by LGL Limited in the form of an Access database and an Excel spreadsheet.

Statistical Analysis

Hierarchical Bayesian models were fitted to the count data using R version 3.2.3 (Team 2013) and JAGS 4.0.1 (Plummer 2015) which interfaced with each other via jaggernaut 2.3.1 (Thorley 2013). For additional information on hierarchical Bayesian modelling in the BUGS language, of which JAGS uses a dialect, the reader is referred to (Kery and Schaub 2011, 41–44).

Unless specified, the models assumed vague (low information) prior distributions (Kery and Schaub 2011, 36). The posterior distributions were estimated from a minimum of 1,000 Markov Chain Monte Carlo (MCMC) samples thinned from the second halves of three chains (Kery and Schaub 2011, 38–40). Model convergence was confirmed by ensuring that Rhat (Kery and Schaub 2011, 40) was less than 1.1 for each of the parameters in the model (Kery and Schaub 2011, 61).

The posterior distributions of the fixed (Kery and Schaub 2011, 75) parameters are summarised in terms of a point estimate (median), lower and upper 95% credible limits (2.5th and 97.5th percentiles), the standard deviation (SD), percent relative error (half the 95% credible interval as a percent of the point estimate) and significance (Kery and Schaub 2011, 37, 42).

Variable selection was achieved by dropping insignificant (Kery and Schaub 2011, 37, 42) fixed (Kery and Schaub 2011, 77–82) variables and uninformative random variables. A fixed variables was considered to be insignificant if its significance was \(\geq\) 0.05 while a random variable was considered to be uninformative if its percent relative error was \(\geq\) 80%. The Deviance Information Criterion (DIC) was not used because it is of questionable validity when applied to hierarchical models (Kery and Schaub 2011, 469).

The results are displayed graphically by plotting the modelled relationships between particular variables and the response with 95% credible intervals (CRIs) with the remaining variables held constant. In general, continuous and discrete fixed variables are held constant at their mean and first level values respectively while random variables are held constant at their typical values (expected values of the underlying hyperdistributions) (Kery and Schaub 2011, 77–82). Where informative the influence of particular variables is expressed in terms of the effect size (i.e., percent change in the response variable) with 95% CRIs (Bradford, Korman, and Higgins 2005).

Observer Efficiency

The aerial observer efficiency was estimated from ground counts using a Poisson model. Key assumptions of the observer efficiency model include:

• Spawner abundance at a site does not vary between the ground and aerial count.
• Ground observers are unbiased.
• Ground counts are drawn from a Poisson distribution.
• Aerial counts are drawn from an overdispersed Poisson distribution.
• Aerial observer efficiency does not vary with abundance or channel type (side versus main channel).

Area-Under-the-Curve

The aerial spawner counts were analysed using a hierarchical Bayesian Area-Under-the-Curve (AUC) model (Hilborn, Bue, and Sharr 1999). Key assumptions of the AUC model include:

• Spawner arrival and departure times are normally distributed (Hilborn, Bue, and Sharr 1999).
• Spawner duration is constant across years.
• Spawner abundance varies randomly by year, drawn from a normal distribution.
• Peak spawn timing varies randomly by year, drawn from a normal distribution (Su, Adkison, and Van Alen 2001).
• Spawner residence time is between 7 and 14 days (Acara 1970, @morbey_timing_2003).
• Spawner observer efficiency is drawn from a normal distribution as estimated by the observer efficiency model, with a mean of 1.05, SD of 0.15 and lower and upper limits of 0.79 and 1.36 respectively.
• The residual variation in the spawner counts is normally distributed.

Model Code

The JAGS model code, which uses a series of naming conventions, is presented below.

model{

  bEfficiency ~ dunif(0, 3)

  bAbundance ~ dnorm(5, 5^-2)
  sAbundance ~ dunif(0, 5)

  sDispersion ~ dunif(0, 5)
  for (i in 1:length(Aerial)){

    eEfficiency[i] <- bEfficiency

    eAbundance[i] ~ dlnorm(bAbundance, sAbundance^-2)
    Ground[i] ~ dpois(eAbundance[i])

    eAerial[i] <- eAbundance[i] * eEfficiency[i]
    eDispersion[i] ~ dgamma(1 / sDispersion^2, 1 / sDispersion^2)
    Aerial[i] ~ dpois(eAerial[i] * eDispersion[i])
  }
}

model{

  bEfficiency ~ dnorm(1.05, 0.15^-2) T(0.79, 1.36)

  bAbundance ~ dnorm(10, 5^-2)
  bPeakTiming ~ dnorm(0, 5)
  bDuration ~ dunif(0, 42)

  sAbundanceYear ~ dunif(0, 5)
  sPeakTimingYear ~ dunif(0, 28)
  for(i in 1:nYear){
    bAbundanceYear[i] ~ dnorm(0, sAbundanceYear^-2)
    bPeakTimingYear[i] ~ dnorm(0, sPeakTimingYear^-2)
  }

  bResidenceTime ~ dunif(7, 14)

  sCount ~ dunif(0, 10000)
  for(i in 1:length(Count)){

    log(eAbundance[i]) <- bAbundance + bAbundanceYear[Year[i]]

    ePeakTiming[i] <- bPeakTiming + bPeakTimingYear[Year[i]]

    eDuration[i] <- bDuration

    eSpawners[i] <- ( phi((Dayte[i] - (ePeakTiming[i] - bResidenceTime/2)) / eDuration[i])
                     -phi((Dayte[i] - (ePeakTiming[i] + bResidenceTime/2)) / eDuration[i])
                    ) * eAbundance[i]

    eEfficiency[i] <- bEfficiency

    eCount[i] <- eSpawners[i] * eEfficiency[i]
    Count[i] ~ dnorm(eCount[i], sCount^-2)
  }
} 

Model Parameters

The posterior distributions for the fixed (Kery and Schaub 2011 p. 75) parameters in each model are summarised below.

Figures

Observer Efficiency

Area-Under-The-Curve