Kootenay Lake Gerrard Rainbow Trout Condition and Growth Analysis 2014

Data Preparation

The length, weight, fecundity and kokanee information was provided by RedFish Consulting Ltd. Scale ages were determined by Greg Andrusak (RedFish Consulting Ltd.), Carol Lidstone (Birkenhead Scale Analyses) and Les Fleck. Scale radii at annuli and scale lengths were provided by Greg Andrusak. The data were cleansed, tidied and manipulated prior to analysis using R version 3.1.2 (Team 2013).

Statistical Analysis

Hierarchical Bayesian models were fitted to the count data using R version 3.1.2 (Team 2013) and JAGS 3.4.0 (Plummer 2012) which interfaced with each other via jaggernaut 2.2.8 (Thorley 2013). For additional information on hierarchical Bayesian modelling in the BUGS language, of which JAGS uses a dialect, the reader is referred to Kery and Schaub (2011, 41–44).

Unless specified, the models assumed vague (low information) prior distributions (Kery and Schaub 2011, 36). The posterior distributions were estimated from a minimum of 1,000 Markov Chain Monte Carlo (MCMC) samples thinned from the second halves of three chains (Kery and Schaub 2011, 38–40). Model convergence was confirmed by ensuring that Rhat (Kery and Schaub 2011, 40) was less than 1.1 for each of the parameters in the model (Kery and Schaub 2011, 61). Model adequacy was confirmed by examination of residual plots.

The posterior distributions of the fixed (Kery and Schaub 2011, 75) parameters are summarised in terms of a point estimate (mean), lower and upper 95% credible limits (2.5th and 97.5th percentiles), the standard deviation (SD), percent relative error (half the 95% credible interval as a percent of the point estimate) and significance (Kery and Schaub 2011, 37, 42).

Variable selection was achieved by dropping insignificant (Kery and Schaub 2011, 37, 42) fixed (Kery and Schaub 2011, 77–82) variables and uninformative random variables. A fixed variables was considered to be insignificant if its significance was \(\geq\) 0.05 while a random variable was considered to be uninformative if its percent relative error was \(\geq\) 80%.

The results are displayed graphically by plotting the modeled relationships between particular variables and the response with 95% credible intervals (CRIs) with the remaining variables held constant. In general, continuous and discrete fixed variables are held constant at their mean and first level values respectively while random variables are held constant at their typical values (expected values of the underlying hyperdistributions) (Kery and Schaub 2011, 77–82). Where informative the influence of particular variables is expressed in terms of the effect size (i.e., percent change in the response variable) with 95% CRIs (Bradford, Korman, and Higgins 2005).

Fecundity

The relationship between fork length and the egg count was estimated using an allometric model. Key assumptions of the fecundity model include:

• The residual egg counts are log-normally distributed.

Condition

The relationship between body weight and fork length was estimated using an allometric mass-length model similar to He and Bence (2008). Key assumptions of the condition model include:

• The weight varies with the length.
• The weight varies with the day of the year as a second order polynomial.
• The weight varies randomly with the year
• The residual weight is log-normally distributed.

Backcalculated Growth

The relative growth in any given year was estimated from the scale increments using a polynomial model. Key assumptions of the polynomial model include:

• The scale increment varies with the scale radius as a second order polynomial.
• The scale increment varies randomly by year.
• The residual variation which is log-normally distributed varies with the reader’s minimum confidence in the two annuli.

Preliminary analyses indicated that the fork length of the fish at capture and fish ID as a random effect were not informative predictors of scale increment.

Dynamic Factor Analysis

The relative similarities between the yearly condition and growth (scale increment) estimates and the yearly kokanee abundance estimates were estimated using a Dynamic Factor Analysis (Zuur, Tuck, and Bailey 2003). Due to the rotation problem the underlying trends were indeterminate (Abmann, Boysen-Hogrefe, and Pape 2014). The growth estimates were lagged by one year.

Key assumptions of the DFA model include:

• The time series are described by two underlying trends.
• The random walk processes in the trends are normally distributed.
• The residual variation in the standardised variables is normally distributed.

Model Code

The JAGS model code, which uses a series of naming conventions, is presented below.

model {

  bAlpha ~ dnorm(5, 5^-2)
  bBeta ~ dnorm(1, 5^-2)

  sFecundity ~ dunif(0, 1)
  for(i in 1:length(Fecundity)) {
    log(eFecundity[i]) <- bAlpha + bBeta * Length[i]
    Fecundity[i] ~ dlnorm(log(eFecundity[i]), sFecundity^-2)
  }
}

model {

  bAlpha ~ dnorm(5, 5^-2)
  bBeta ~ dnorm(3, 5^-2)

  bAlphaDayte ~ dnorm(0, 5^-2) 
  bAlphaDayte2 ~ dnorm(0, 5^-2)

  sAlphaYear ~ dunif(0, 5)
  for(i in 1:nYear) {
    bAlphaYear[i] ~ dnorm(0, sAlphaYear^-2)
  }  

  sWeight ~ dunif(0, 5)
  for(i in 1:length(Weight)) {
    eAlpha[i] <- bAlpha + bAlphaDayte * Dayte[i] + bAlphaDayte2 * Dayte[i]^2 + bAlphaYear[Year[i]]

    eBeta[i] <- bBeta

    log(eWeight[i]) <- eAlpha[i] + eBeta[i] * Length[i]

    Weight[i] ~ dlnorm(log(eWeight[i]), sWeight^-2)
  }
}

 model {
  bLInf ~ dunif(700, 1000)
  bK ~ dunif(0, 1)
  t0 ~ dnorm(0, 2^-1)

  bKReader[1] <- 0
  bT0Reader[1] <- 0
  for(i in 2:nReader) {
    bKReader[i] ~ dnorm(0, 1^-2)
    bT0Reader[i] ~ dnorm(0, 5^-2)
  }

  sKFish ~ dunif(0, 1)
  for(i in 1:nFish) {
    bKFish[i] ~ dnorm(0, sKFish^-2)
  }

  sLength ~ dunif(0, 100)    
  for (i in 1:length(Length)) {
    eLInf[i] <- bLInf
    log(eK[i]) <- log(bK) + bKReader[Reader[i]] + bKFish[Fish[i]]
    eT0[i] <-  t0 + bT0Reader[Reader[i]]
    eLength[i] <- eLInf[i] * (1 - exp(-eK[i] * (Age[i] - eT0[i]))) 
    Length[i] ~ dnorm(eLength[i], sLength^-2)
  }
}

model {

  bInc ~ dnorm(0, 5^-2)
  bIncScaleRadius ~ dnorm(0, 5^-2)
  bIncScaleRadius2 ~ dnorm(0, 5^-2)

  sIncYear ~ dunif(0, 5)
  for (i in 1:nYear) {
    bIncYear[i] ~ dnorm(0, sIncYear^-2)
  }

  bSDInc ~ dnorm(0, 5^-2)
  bSDIncProbability ~ dnorm(0, 5^-2)
  for (i in 1:length(ScaleRadius)) {

    log(eInc[i]) <- bInc + bIncScaleRadius * ScaleRadius[i] + bIncScaleRadius2 * ScaleRadius[i]^2 + bIncYear[Year[i]]

    log(eSDInc[i]) <- bSDInc + bSDIncProbability * Probability[i]

    Increment[i] ~ dlnorm(log(eInc[i]), eSDInc[i]^-2)
  }
} 

model{

  sTrend ~ dunif(0, 1)
  for (t in 1:nTrend) {
    bTrendYear[t,1] ~ dunif(-1,1)
    for(y in 2:nYear){
      bTrendYear[t,y] ~ dnorm(bTrendYear[t,y-1], sTrend^-2)
    }
  }

  for(v in 1:nVariable){ 
    for(t in 1:nTrend) {
      Z[v,t] ~ dunif(-1,1)
    }
    for(y in 1:nYear){
      eValue[v,y,1] <- Z[v,1] * bTrendYear[1,y]
      for(t in 2:nTrend) {
        eValue[v,y,t] <- eValue[v,y,t-1] + Z[v,t] * bTrendYear[t,y]
      }
    }
  }

  sValue ~ dunif(0, 1)
  for(i in 1:length(Value)) {
    Value[i] ~ dnorm(eValue[Variable[i], Year[i], nTrend], sValue^-2)
  }

  for(i in 1:nVariable) {
    for(j in 1:nVariable) {
      bDistance[i,j] <- sqrt(sum((Z[i,]-Z[j,])^2))
    }
  }
}

Model Parameters

The posterior distributions for the fixed (Kery and Schaub 2011 p. 75) parameters in each model are summarised below.

Figures

Condition

Age

Back-Calculated Growth

Dynamic Factor Analysis