Kaslo Bull Trout Productivity 2022

Length Correction

The annual bias (inaccuracy) and error (imprecision) in observer’s fish length estimates when spotlighting (standing) and snorkeling were quantified from the divergence of their length distribution from the length distribution for JLT and SH (the two most experience snorkelers) in that year. More specifically, the length correction that minimised the Jensen-Shannon divergence (Lin 1991) provided a measure of the inaccuracy while the minimum divergence (the Jensen-Shannon divergence was calculated with log to base 2 which means it lies between 0 and 1) provided a measure of the imprecision.

Observer Efficiency

All resighted fish with a tag were allocated to the closest unallocated marked fish (with the same colour tag) by fork length and distance. The marked fish were analysed using a Bayesian logistic regression model. The key assumption of the logistic regression model is that:

• The observer efficiency varies by the fork length.

The preliminary analysis for observer efficiency indicated that system, observer, gradient, sinuosity, and river kilometre were not informative predictors.

Lineal Density

Both systems were broken into 100 m sites by bank. The lineal density at each site was estimated using an over-dispersed Poisson Generalized Linear Mixed Model.

Key assumptions of the Bayesian GLMM include:

• The lineal density varies by system and stream distance.
• The lineal density varies randomly by site and system within year.
• The observer efficiency for each system is as estimated by the observer efficiency model.

The preliminary analysis for density indicated that site sinuosity and gradient were not informative predictors of lineal density.

Condition

The condition of adults was estimated using an allometric weight-length relationship. Key assumptions of the condition model include:

• Weight varies by length.
• Weight varies randomly by year.
• The residual variation in weight is log normally distributed.

Fecundity

Female spawner fecundity was estimated using an allometric egg-weight relationship. The key assumptions of the fecundity model include:

• Fecundity varies with weight.
• The residual variation in fecundity is log normally distributed.

Spawner Length

The average length of spawners in each system and year was estimated using a linear regression. Key assumptions of the spawner length model include:

• Length varies randomly with system, year, and system within year.
• Length varies with sex and catch type.
• The residual variation is normally distributed.

Egg Deposition

The total egg deposition in each year was estimated by

• Converting the average spawner length to the average weight using the condition relationship for a typical year.
• Adjusting the average weight by the annual condition effect (interpolating where unavailable)
• Converting the average weight to the average fecundity using the fecundity relationship
• Multiplying the average fecundity by the number of females (assuming 1 female per redd)

Eggs Stock-Recruitment

The stock-recruitment relationship between the total number eggs and the abundance of age-1 individuals was estimated using a Bayesian Beverton-Holt stock-recruitment curve. Key assumptions of the final BH SR model include:

• The prior uncertainty in the egg to age-1 survival is described by a Beta distribution with an alpha of 4 and beta of 49 which has a mean of 0.075 and a standard deviation of 0.036. This is based off the assumption that a recruit has a ~50% chance of surviving through each summer or winter and must pass through two winters and two summers to survive to age-1.
• The carrying capacity varies between systems.
• The residual variation in the recruits is log normally distributed.

The \(E_{K/2}\) Limit Reference Point (Mace 1994) (\(E_{0.5 R_{max}}\)) was calculated, corresponding to the stock (number of eggs per 100 meters) that produce 50% of the maximum recruitment (\(K\)).

Observer Efficiency

.model{
  bIntercept ~ dnorm(0, 2^-2)
  bLength ~ dnorm(0, 2^-2)

  for(i in 1:length(Observed)){
    logit(eObserved[i]) <-  bIntercept + bLength * Length[i]
    Observed[i] ~ dbern(eObserved[i])
  }

Block 1. Final model.

Lineal Density

.model{
  bEfficiency ~ dnorm(Efficiency[1], EfficiencySD[1]^-2) T(0, 1)

  b0 ~ dnorm(0, 5^-2)
  bRkm ~ dnorm(0, 2^-2)
  bSystem[1] <- 0
  for(i in 2:nSystem) {
    bSystem[i] ~ dnorm(0, 2^2)
  }

  sSystemYear ~ dnorm(0, 2^-2) T(0,)
  for(i in 1:nSystem) {
    for(j in 1:nYear) {
      bSystemYear[i,j] ~ dnorm(0, sSystemYear^-2)
    }
  }

  sSite ~ dnorm(0, 2^-2) T(0,)
  for(i in 1:nSite) {
    bSite[i] ~ dnorm(0, sSite^-2)
  }

  sDispersion ~ dnorm(0, 2^-2) T(0,)
  for(i in 1:length(Count)) {
    log(eDensity[i]) <- b0 + bSystem[System[i]] + bRkm * Rkm[i] + bSite[Site[i]] + bSystemYear[System[i],Year[i]]
    eDispersion[i] ~ dgamma(sDispersion^-2, sDispersion^-2)
    Count[i] ~ dpois(eDensity[i] * Length[i] * Coverage[i] * bEfficiency * eDispersion[i])
  }

Block 2. The final model.

Condition

.model{
  b0 ~ dnorm(6, 2^-2)
  bLength ~ dnorm(3, 1^-2)
  sWeight ~ dnorm(0, 1^-2) T(0,)
  sYear ~ dnorm(0, 1^-2) T(0,)

  for (i in 1:nYear) {
    bYear[i] ~ dnorm(0, sYear^-2)
  }

  for (i in 1:nObs) {
    log(eWeight[i]) <- b0 + (log(Length[i]) - log(500)) * bLength + bYear[Year[i]]
    Weight[i] ~ dlnorm(log(eWeight[i]), sWeight^-2)
  }

Block 3. Model description.

Fecundity

.model{
  b0 ~ dnorm(0, 2^-2)
  bWeight ~ dnorm(1, 2^-2)
  sFecundity ~ dnorm(0, 2^-2) T(0,)

  for (i in 1:nObs) {
    log(eFecundity[i]) <- b0 + (log(Weight[i]) - log(2300)) * bWeight
    Fecundity[i] ~ dlnorm(log(eFecundity[i]), sFecundity^-2)
  }

Block 4. Model description.

Spawner Length

.model{
  bLength ~ dnorm(650, 100^-2)
  sLength ~ dnorm(0, 100^-2) T(0,)
  sYear ~ dnorm(0, 100^-2) T(0,)
  sSystem ~ dnorm(0, 100^-2) T(0,)
  sYearSystem ~ dnorm(0, 100^-2) T(0,)
  bSex ~ dbeta(1, 1)
  bFemale ~ dnorm(0, 100^-2)
  bBias ~ dnorm(0, 100^-2)

  for (i in 1:nYear) {
    bYear[i] ~ dnorm(0, sYear^-2)
  }

  for (i in 1:nSystem) {
    bSystem[i] ~ dnorm(0, sSystem^-2)
  }

  for (i in 1:nYear) {
    for (j in 1:nSystem) {
        bYearSystem[i, j] ~ dnorm(0, sYearSystem^-2)
    }
  }

  bCatchType[1] <- 0
  for(i in 2:nCatchType) {
    bCatchType[i] ~ dnorm(0, 100^-2)
  }

  for (i in 1:nObs) {
    Female[i] ~ dbern(bSex)
    eLength[i] <- bLength + bSystem[System[i]] + bFemale * Female[i] + bCatchType[CatchType[i]] + bYear[Year[i]] + bYearSystem[Year[i], System[i]] + bBias * Bias[i]
    Length[i] ~ dnorm(eLength[i], sLength^-2)
  }

Block 5. Model description.

Stock-Recruiment

.model {
  bAlpha ~ dbeta(4, 49)

  bK ~ dnorm(3, 1^-2)
  bKPopulation ~ dnorm(0, 1^-2)
  sRecruits ~ dexp(1)

  for(i in 1:nObs){
    log(eK[i]) <- bK + (Kaslo[i] * bKPopulation - (1-Kaslo[i]) * bKPopulation)
    eBeta[i] <-  bAlpha/eK[i]
    eRecruits[i] <- bAlpha * Stock[i] / (1 + eBeta[i] * Stock[i])
    Recruits[i] ~ dlnorm(log(eRecruits[i]), sRecruits^-2)
  }

Block 6. Final model.

Coverage

Table 1. Total length of river bank counted (including replicates) by system and year.

Observer Efficiency

Table 2. Parameter descriptions.

Table 3. Final parameter estimates.

Table 4. Observer Efficiency estimates for a 123 mm Bull Trout.

Table 5. Final model summary.

Table 6. Model posterior predictive checks.

Table 7. Model sensitivity.

Lineal Density

Table 8. Parameter descriptions.

Table 9. Parameter estimates.

Table 10. Model summary.

Table 11. Model posterior predictive checks.

Table 12. Model sensitivity.

Condition

Table 13. Parameter descriptions.

Table 14. Model coefficients.

Table 15. Model convergence.

Table 16. Model posterior predictive checks.

Table 17. Model sensitivity.

Fecundity

Table 18. Parameter descriptions.

Table 19. Model coefficients.

Table 20. Model convergence.

Table 21. Model posterior predictive checks.

Table 22. Model sensitivity.

Spawner Length

Table 23. Parameter descriptions.

Table 24. Model coefficients.

Table 25. Model convergence.

Table 26. Model posterior predictive checks.

Table 27. Model sensitivity.

Egg Deposition

Table 28. The estimated total egg deposition by system and year.

Stock-Recruiment

Table 29. Parameter descriptions.

Table 30. Density Carrying Capacity (K).

Table 31. Model coefficients.

Table 32. Model convergence.

Table 33. Ek/2 Limit Reference Point estimates.

Table 34. Model posterior predictive checks.

Table 35. Model sensitivity.

Systems

Coverage

Sites

Length Correction

Fish

Observer Efficiency

Lineal Density

Redds

Condition

Fecundity

Spawner Length

Egg Deposition

Stock-Recruiment